20 tool umbrella install trouble with oak <resolved>

[rjtechserv]

This is my first umbrella tool changer install.

I've almost got it I think but, when requesting a MDI tool change. T19 M6. The spindle orients and confirms next the umbrella moves in triggers it's switch and the umbrella leaves right away but, still says waiting for Carousel In... the switch works... odd

Not sure why it would retract before releasing the drawbar and z going up. Up to Home? No idea on that yet.

[rjtechserv]

Added the report.

[cncsnw]

See lines 3616-3629 of your PLC program.

Your PLC program assumes a two-coil detented solenoid valve (one that stays in one position or the other, even after you turn off power to the coil). Most common Centroid umbrella-ATC programs turn off carousel advance/retract solenoid power as soon as the sensor is made to show that the move is complete.

My guess is that your machine has a single-coil spring-return solenoid valve, which returns to the "carousel retract" condition as soon as "carousel advance" coil power is turned off. Do you have a second coil wired to OUT32? Or just one, wired to OUT31?

If you have a single-coil, spring-return valve, then you will need to edit the PLC program to just SET the advance solenoid (and leave it set) when the carousel needs to advance, and RST the advance solenoid when the carousel needs to retract.

[rjtechserv]

I think that's right. It's a single solenoid. I'll let you know how it goes. Much appreciated.

Rob

[rjtechserv]

For anyone who may need it; These are the changes to part of the "ATC Carousel" section of the OAK PLC

;------------------------------------------------------------------------------
; ATC Carousel - Dual Solenoid; CarouselOutSol_O AND CarouselInSol_O
;------------------------------------------------------------------------------
;Carousel In
IF ZeroSpeed_I && ((OrientComplete_I && M80_SV && M6_SV) || (M80_SV && Aux14Key_I))
THEN RST M81_SV, SET CarouselInSol_O, SET CarouselInOutTimer_T,
SET MovingCarouselIn_M, RST MovingCarouselOut_M

IF SV_STOP || !SV_PROGRAM_RUNNING || (MovingCarouselIn_M && CarouselIsIn_I)
THEN RST CarouselInSol_O, RST M80_SV

;CarouselOut
IF (M81_SV && M6_SV) || (M81_SV && Aux14Key_I)
THEN RST M80_SV, SET CarouselOutSol_O, SET CarouselInOutTimer_T,
SET MovingCarouselOut_M, RST MovingCarouselIn_M

IF SV_STOP || !SV_PROGRAM_RUNNING || (MovingCarouselOut_M && CarouselIsOut_I)
THEN RST CarouselOutSol_O, RST M81_SV

################ Change Break Line ##############################################

;------------------------------------------------------------------------------
; ATC Carousel - Single Solenoid; CarouselInSol_O ONLY!
;------------------------------------------------------------------------------
;Carousel In
IF ZeroSpeed_I && ((OrientComplete_I && M80_SV && M6_SV) || (M80_SV && Aux14Key_I))
THEN RST M81_SV, SET CarouselInSol_O, SET CarouselInOutTimer_T,
SET MovingCarouselIn_M, RST MovingCarouselOut_M

IF SV_STOP || !SV_PROGRAM_RUNNING || (MovingCarouselIn_M && CarouselIsIn_I)
THEN RST M80_SV

;CarouselOut
IF (M81_SV && M6_SV) || (M81_SV && Aux14Key_I)
THEN RST M80_SV, RST CarouselInSol_O, SET CarouselInOutTimer_T,
SET MovingCarouselOut_M, RST MovingCarouselIn_M

IF SV_STOP || !SV_PROGRAM_RUNNING || (MovingCarouselOut_M && CarouselIsOut_I)
THEN RST CarouselInSol_O, RST M81_SV